Belgian Amiga Club - ADF Collection/BS1 part 05.zip/BS1 part 5/IM_3 .adf/Exec/piarc.LZH/targaw.rexx

OS/2 REXX Batch file | 1992-04-09 | 5KB | 204 lines

/*
 * targaw.rexx
 *
 *  Written by: Pete Patterson & Ben Williams
 * Last Update: April 18, 1992
 *         For: Black Belt Systems image processing series IM, IM F/c, and IP.
 * ---------------------------------------------------------------------------
 *    Revision: 1.02
 */

/*
 * open rexxsupport.library -- needed for some functions
 */
if ~show('L',"rexxsupport.library") then do
  if addlib('rexxsupport.library',0,-30,0) then do
      /* everything's ok */
    end;
  else do
    say 'We Have A Library Problem, Unable To Load "rexxsupport.library"';
    say 'Cannot operate targaw.rexx without this library - sorry!';
    exit 10;
    end;
  end;

/*
 * This will automatically direct the script to the proper
 * software, if it is running.
 */
prtnme = 'IP_Port'; /* assume Image Professional */
if show('P','IP_Port') = 0 then do
  if show('P','IM_Port') = 0 then do
    say "Can't find image processor's ARexx port!!!"; /* not running? */
    say "This script requires IP, IM or IM F/c to run!";
    exit(20);
    end;
  else do
    prtnme = 'IM_Port'; /* That's the thing about assumptions... */
    end;                 /* We make em, user's break em.          */
  end;

  /*
   * This code attempts to read a file called "picmdpath" from REXX:
   * If it can't find it, the script will assume that the commands
   * associated with this PI Module are in "c:". If the file exists,
   * the script will look in the path that is specified in the file.
   * If you create this file, you MUST put a complete, correct path
   * in it; if the commands are in a sub-directory, you have to put
   * the trailing slash on the path (like, device:dir/).
   *
   */
  cmdpath = 'c:';
  if open(fhandle,'rexx:picmdpath','read') then  /* open the file */
    do
      cmdpath = readln(fhandle);
      call close(fhandle);  /* close the file    */
    end

options;
address;

  prevpath = 'ram:'; /* put user in ram to start with... */

  if show('C',targapath) = 1 then do
    prevpath = getclip(targapath);
    end;

  address(prtnme);
  options results;
  'current';
  bufdata = result; /* get name of buffer, if there is one */
  parse var bufdata bname ',' bnum ',' bx ',' by ',' btot ',' bmem ',' bparname ',' bparnum;
  if bname ~= '<none>' then do
    bufname = bname;
    end;
  if (length(bufname) > 4) then do
    epos = pos('.tga',bufname,length(bufname)-3);
    if epos ~= 0 then do
      bufname = left(bufname,epos-1)
      end
    end;
  'filerequest "'||prevpath||'","'||bufname||'",".tga","Save TARGA"';
  TARGAfile = result;
  options;

  if TARGAfile = 'FR_CANCELLED' then do
    address(prtnme);
    'imtofront';
    exit 0;
    end;

  TARGAfile = expandfilename(TARGAfile);
  thispath = gimmepath(TARGAfile);
  call setclip(targapath,thispath);

  address(prtnme);

'tofront';

options results;
'gadgets "16 Bit","Targa","24 Bit","Targa","32 Bit","Targa"';
pxsz = result-1;
options;
if pxsz < 0 then do
  address;
  exit 0;
  end

options results;
'gadgets "Compressed","Data","No","Compression"';
comp = result-1;
options;
if comp < 0 then do
  address;
  exit 0;
  end

/*
options results;
'gadgets "Use","Color Table","No","Color Table"';
tbl = result-1;
options;
if tbl < 0 then do
  address;
  exit 0;
  end;

ptype = 0;
if comp = 1 & tbl = 0 then ptype = 1;
if comp = 1 & tbl = 1 then ptype = 2;
if comp = 0 & tbl = 0 then ptype = 9;
if comp = 0 & tbl = 1 then ptype = 10;
*/
ptype = 0;
if comp = 1 then ptype = 2;
if comp = 0 then ptype = 10;

  options results;
  'jackin';
  jackadr = result;
  options;

  'wbtofront';
  'lockimage '||bnum;
  address command cmdpath||'targaw '||jackadr||' '||ptype||' '||pxsz||' "'||TARGAfile||'"';
  'unlockimage '||bnum;

  address(prtnme);
  'imtofront';
  address;

  exit 0;

/*
 * gimmepath
 *
 * This takes the provided argument and sucks the path out of it, then
 * returns that path to the caller, sans file name.
 */
gimmepath:
  arg fullnamegx;
    tempgx = reverse(fullnamegx);
    lengx = length(fullnamegx);   /* get length of string */
    slashdex = index(tempgx,'/'); /* first occurance of '/' from right */
    colondex = index(tempgx,':');  /* first occurance of ':' from right */
    seploc = 0; /* assumes current dir, no path supplied */
    if slashdex ~= 0 then do /* we assume we are in a DIR */
      seploc = (lengx - slashdex)+1;
      end;
    else do
      if colondex ~= 0 then do /* we assume we are on a device */
        seploc = (lengx - colondex)+1;
        end;
      end;
  gxname = substr(fullnamegx,seploc+1); /* if you ever need it */
  gxpath = left(fullnamegx,seploc);
  return(gxpath);

/*
 * Since this script can't be expected to know where the CD of the user
 * is when this cmd is invoked, we have to check the path the user
 * provides - if it's not specified right from a root, then we have
 * to make it a complete specification from the root.
 */
expandfilename:
  parse arg jfile;
  if index(jfile,':') = 0 then do
    curdir = pragma(D);
    if right(curdir,1) ~= ':' then do
      if right(curdir,1) ~= '/' then do
        if curdir ~= '' then do
          curdir = curdir || '/';
          end;
        end;
      end;
    jfile = curdir||jfile;
    end;
  return(jfile);

rvalue:
  wordnum = c2d(readch(fhandle,1)) * 256;
  wordnum = wordnum + c2d(readch(fhandle,1));
  return wordnum;